home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Apple II Magazines (PO)
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A)[a].zip
/
Nibble Volume 12, No. 12 (1991-12)(MindCraft Publishing)(Side A)[a].po
/
PRODOS.ID.bas
< prev
next >
Wrap
BASIC Source File
|
1996-12-24
|
1KB
|
25 lines
10 REM PROGRAM PRODOS.ID
20 REM THIS USES BIT.BREAKER TO TAKE APART
30 REM THE PRODOS MACHINE ID BYTE
40 REM BITS 3,6,7 INDICATE MACHINE TYPE
50 REM BITS 4,5 INDICATE MEMORY SIZE
60 REM BIT 1 INDICATES 80 COLUMN STATUS
70 REM BIT O INDICATES CLOCK STATUS
80 HOME :N = PEEK(49048)
90 PRINT "PRODOS MACHINE ID BYTE DECODED": PRINT
100 FOR BT = 0 TO 7
110 V = (N - INT(N/2) *2): PRINT "BIT ";BT;" IS ";V:D(BT) = V
120 N = INT(N/2): REM REDUCE VALUE
130 NEXT : PRINT
140 IF D(3) = 0 AND D(6) = 0 AND D(7) = 0 THEN PRINT "THE COMPUTER IS A II"
150 IF D(3) = 0 AND D(6) = 1 AND D(7) = 0 THEN PRINT "THE COMPUTER IS A II+"
160 IF D(3) = 0 AND D(6) = 0 AND D(7) = 1 THEN PRINT "THE COMPUTER IS A IIE"
170 IF D(3) = 0 AND D(6) = 1 AND D(7) = 1 THEN PRINT "THE COMPUTER IS A III"
180 IF D(3) = 1 AND D(6) = 0 AND D(7) = 1 THEN PRINT "THE COMPUTER IS A IIC"
190 IF D(4) = 0 AND D(5) = 0 THEN PRINT "MEMORY IS 48K"
200 IF D(4) = 0 AND D(5) = 1 THEN PRINT "MEMORY IS 64K"
210 IF D(4) = 1 AND D(5) = 1 THEN PRINT "MEMORY IS 128K"
220 IF D(1) = 0 THEN PRINT "NO 80 COLUMN DISPLAY HARDWARE FOUND"
230 IF D(1) = 1 THEN PRINT "STANDARD 80 COLUMN DISPLAY FOUND"
240 IF D(0) = 0 THEN PRINT "NO PRODOS CLOCK IS PRESENT"
250 IF D(0) = 1 THEN PRINT "PRODOS CLOCK IS PRESENT"